当前位置 : 主页>技术研究>传世技术>

传世版本国战相关属性

来源: 作者: 点击:
国战相关属性
属性说明
国王可以设定一个国王,国王的设定可以通过同一国家的定期比武确认
经济国民通过杀怪获得的金钱将累计到国家经济实力上(以后还会增加其他提升国家经济实力的途径)
政治是该国家吸引人才的能力,每新加入一个成员,则该国的政治实力会加上该新成员的等级数,同样,如果一个国民离开这个国家,则减去该国民当前等级数
军事杀外国国民时,本国的军事相应的增加被杀人物等级的
人口本国的国民数
地图地图拥有国家属性(使用参数COUNTRY(n),n是国家编号),如果地图的国家是0,表示公共地图,所有国家的国民可以在此地图活动。

其他国家国民(不包括没有国家的游民)进入非本国地图时,拥有这个地图的国家的国民都将收到入侵警告,被杀死的入侵者将会被扣除相应等级的军事积分
地图争霸可以开放一些地图争霸赛,赢的国家将拥有这个地图的所有权。
王城地图每个国家可以设置一个王城地图
国王争霸每个国家每周举行一次国王争霸赛,第一轮为全体国民大PK(国王不参与),剩下的8个人由他们自己组织分成4组,再由这4组的胜利方进行2组PK,剩下的2个人再进行决战。决战胜利者将有权利和国王PK,战胜国王即可赢得国王称号,没有国王的则直接由决战胜利者担任国王




设置当前人物的国家编号
SetCountry Parameters
命令参数
参数说明
Parameters国家编号


命令作用
设置当前人物的国家编号
补充说明
同时会设置该人物的元神的国家为和玩家相同
对应GM命令: SetCountry 人物名称 国家编号
使用示例
[@SetCountry]
#IF
True
#ACT
SetCountry 1
#SAY
你加入了编号为1的国家。



设置当前人物的官衔等级
SETTITLELEVEL Parameters
命令参数
参数说明
Parameters等级编号


命令作用
设置当前人物的官衔等级
补充说明
必须加入国家才可以设置
使用示例
[@SETTITLELEVEL]
#IF
True
#ACT
SETTITLELEVEL 1
#SAY
你现在的官衔为1级。



判断当前人物是否属于该国家
CHECKCOUNTRY Parameters
命令参数
参数说明
Parameters国家编号,0为还没有加入国家。


命令作用
判断当前人物是否属于该国家
补充说明
必须加入国家才可以设置
使用示例
[@CHECKCOUNTRY]
#IF
CHECKCOUNTRY 0
#SAY
你还没有加入任何国家。


改变指定国家的国王
SETKING Parameters PlayerName
命令参数
参数说明
Parameters国家编号
PlayerName玩家名字

命令作用
设置指定国家的国王为这个玩家的名字
使用示例
[@SETKING]
#IF True
#ACT
SETKING 1 $USERNAME
#SAY
恭喜你成为了彩云国(编号:1)的国王。


设置指定地图为某国家领土
SETMAPCOUNTRY Map   Parameters
命令参数
参数说明
Map 地图编号
Parameters国家编号 为0的话则代表此地图为公共地图

命令作用
设置指定地图为这个国家的领地
补充说明
如果是镜像地图,请使用镜像后的地图名
使用示例
[@SETMAPCOUNTRY]
#IF
True
#ACT
SETMAPCOUNTRY 0 1
#SAY
中州已经归属于彩云国所有


国家系统变量——显示某国属性



$COUNTRY(n).Parameters
命令参数
参数说明
n国家编号
Parameters国家属性:
ID:国家编号
NAME:国家名字
KING:国王
MEMBERS:人口数
ECONOMY:经济能力值
ARM:军事能力值
POLITICS:政治能力值
MAPS:国家地图数

命令作用
获得该国家的相关属性



国家系统变量——显示该玩家所属国的相关属性
$MYCOUNTRY.Parameters
命令作用
获得当前人物的所属国家属性
补充说明
Parameters与$COUNTRY(n).Parameters一样。



国家系统变量——获得该玩家的官衔名称
$OFFICIALTITLE(n)
命令参数
参数说明
n该人物的等级编号

命令作用
返回第n级官职名称
配置路径
Envir\官职等级.txt
配置说明
第一个官职的等级为0



国战系统示例脚本
[@main]
#SAY
<加入国家/@加入国家> <查看国家实力/@查看国家实力>\
<没事/@exit>
[@查看国家实力]
#IF
CHECKCOUNTRY 0
#SAY
请选择你要查看的国家:\
{查看<$COUNTRY(1).NAME>实力/@国家实力1}\
{查看<$COUNTRY(2).NAME>实力/@国家实力2} \\
你目前还没有加入任何一个国家。\\
<离开/@exit> <返回/@main>
#elsesay
请选择你要查看的国家:\
{查看<$COUNTRY(1).NAME>实力/@国家实力1}\
{查看<$COUNTRY(2).NAME>实力/@国家实力2} \\
{查看我国<$MYCOUNTRY.NAME>实力/@我国实力}\\
<离开/@exit> <返回/@back>
[@加入国家]
#IF
CHECKCOUNTRY 0
#SAY
在传世大陆上,目前分布着两个国家,一个是{COLOR=RED <$COUNTRY(1).NAME>},一个是{COLOR=RED <$COUNTRY(2).NAME>}。\
{COLOR=RED <$COUNTRY(1).NAME>}目前拥有{COLOR=GREEN <$COUNTRY(1).MEMBERS>}的人口。经济能力为{COLOR=GREEN <$COUNTRY(1).ECONOMY>},军事能力为:{COLOR=GREEN <$COUNTRY(1).ARM>}\
{COLOR=RED <$COUNTRY(2).NAME>}目前拥有{COLOR=GREEN <$COUNTRY(2).MEMBERS>}的人口。经济能力为{COLOR=GREEN <$COUNTRY(2).ECONOMY>},军事能力为:{COLOR=GREEN <$COUNTRY(2).ARM>}\
你想加入哪一个国家呢?\\
{加入<$COUNTRY(1).NAME>/@加入国家1} {加入<$COUNTRY(2).NAME>/@加入国家2} <都没兴趣/@exit>\
#ACT
break
#ELSESAY
你目前已经加入了国家{COLOR=RED <$MYCOUNTRY.NAME>},难道你想判国吗?\
如果判国,将会让你恢复成为{COLOR=RED <$OFFICIALTITLE(0)>},以前所有的战功都将抹去。\\
{加入<$COUNTRY(1).NAME>/@加入国家1} {加入<$COUNTRY(2).NAME>/@加入国家2} <脱离国家/@脱离国家> <不想判国/@exit>\
#ACT
break
[@脱离国家]
#IF
checkcountry 0
#SAY
你还没有加入任何国家!\\
<返回/@main> <离开/@exit>
#elsesay
你真的要脱离你的国家 {COLOR=RED <$MYCOUNTRY.NAME>} 吗?\
脱离国家将收取你1000万金币的户口注销手续费!\\
<脱离/@脱离> <离开/@exit>
[@脱离]
#IF
checkgold 10000000
#act
setcountry 0
take 金币 10000000
sendmsg 11 你已经成功脱离了国家。
close
break
#elsesay
你没有足够的手续费\\
<离开/@exit>
[@加入国家1]
#IF
CHECKCOUNTRY 1
#SAY
你已经是{COLOR=RED <$MYCOUNTRY.NAME>} 的人了。不能重复加入同一个国家。\\
<重新选择/@加入国家> <那就算啦/@exit> <我有其他事情/@main>
#ELSEACT
goto @加入国家1_2
break
[@加入国家1_2]
#IF
#ACT
SETCOUNTRY 1
#SAY
从今天起,你已经正式成为了{COLOR=RED <$COUNTRY(1).NAME>} 的人了。\
为了国家的荣誉,请继续努力,抵御外敌,建立无上战功!\\
<查看国家实力/@国家实力1> <离开/@exit>
#ACT
break
[@加入国家2]
#IF
CHECKCOUNTRY 2
#SAY
你已经是{COLOR=RED <$COUNTRY(2).NAME>} 的人了。不能重复加入同一个国家。\\
<重新选择/@加入国家> <那就算啦/@exit> <我有其他事情/@main>
#ELSEACT
goto @加入国家2_2
break
[@加入国家2_2]
#ACT
SETCOUNTRY 2
#SAY
从今天起,你已经正式成为了{COLOR=RED <$COUNTRY(2).NAME>} 的人了。\
为了国家的荣誉,请继续努力,抵御外敌,建立无上战功!\\
<查看国家实力/@国家实力2> <离开/@exit>

[@我国实力]
#IF
CHECKCOUNTRY 0
#SAY
你还没有加入任何一个国家。\\
<加入国家/@加入国家> <返回/@main> <离开/@exit>
#ACT
break
#IF
CHECKCOUNTRY 1
#ACT
goto @国家实力1
break
#IF
CHECKCOUNTRY 2
#ACT
goto @国家实力2
break
[@国家实力1]
#SAY
国家名称:{COLOR=GREEN <$COUNTRY(1).NAME>}\
国家统领:{COLOR=GREEN <$COUNTRY(1).KING>}\
目前人口:{COLOR=GREEN <$COUNTRY(1).MEMBERS>}\
政治实力:{COLOR=GREEN <$COUNTRY(1).POLITICS>}\
经济实力:{COLOR=GREEN <$COUNTRY(1).ECONOMY>}\
军事实力:{COLOR=GREEN <$COUNTRY(1).ARM>}\
拥有领地:{COLOR=GREEN <$COUNTRY(1).MAPS>} 块\
<返回/@back> <离开/@exit>
[@国家实力2]
#SAY
国家名称:{COLOR=GREEN <$COUNTRY(2).NAME>}\
国家统领:{COLOR=GREEN <$COUNTRY(2).KING>}\
目前人口:{COLOR=GREEN <$COUNTRY(2).MEMBERS>}\
政治实力:{COLOR=GREEN <$COUNTRY(2).POLITICS>}\
经济实力:{COLOR=GREEN <$COUNTRY(2).ECONOMY>}\
军事实力:{COLOR=GREEN <$COUNTRY(2).ARM>}\
拥有领地:{COLOR=GREEN <$COUNTRY(2).MAPS>} 块\
<返回/@back> <离开/@exit>
栏目列表