当前位置 : 主页>技术研究>传奇技术>

独创的传奇版本血剑祭坛脚本鉴赏

来源: 作者: 点击:
[@main]

#IF
#ACT
OPENMERCHANTBIGDLG 8 52 0 0 1 1 1 548 0
#SAY
\ \
<╔═══════════════════════════════════════╗/AUTOCOLOR=150>\
<║/AUTOCOLOR=150> <血祭说明:/SCOLOR=250><【使用血祭之灵,血祭手中的利剑,让它成为万中无一的神器!】/SCOLOR=249> <║/AUTOCOLOR=150>\
<╚═══════════════════════════════════════╝/AUTOCOLOR=150>\ \

<-/AUTOCOLOR=0><血祭相关操作步骤:/SCOLOR=254>\
<-/AUTOCOLOR=0><1、/SCOLOR=58>准备好物品“血祭之灵”放在包裹里!\
<-/AUTOCOLOR=0><2、/SCOLOR=58>把需要血祭的武器装备在手中;血祭过程中不能随便卸装武器!\
<-/AUTOCOLOR=0><3、/SCOLOR=58>系统自动帮你血祭手中武器,血祭最后一次将附加元素属性<(加13%所有伤害元素属性)/SCOLOR=21>!\
<-/AUTOCOLOR=0><4、/SCOLOR=58><血祭一次,装备攻魔道增加1点,目前所有利剑都可以血祭255次,让你HIGH爆!/SCOLOR=168>\
<-/AUTOCOLOR=0><5、/SCOLOR=58>用于血祭的物品<只有活动怪物会掉落,绝不出售!/SCOLOR=253>\
<-/AUTOCOLOR=0><6、/SCOLOR=58>用于血祭的装备血祭255次之前<千万不能加星!否则触发不了属性!/SCOLOR=250>\ \

<-/SCOLOR=0><你的手中装备着利剑/SCOLOR=250>:<【/SCOLOR=58><$WEAPON><】/SCOLOR=58>\ \

<-/SCOLOR=0><你的龙魂银行存放着/SCOLOR=250>:<【/SCOLOR=58><$GAMEDIAMOND><】/SCOLOR=58><-/SCOLOR=0><个血祭之灵/SCOLOR=250> <【/SCOLOR=253><我要存/@存放><】/SCOLOR=253> <【/SCOLOR=168><我要取/@取出><】/SCOLOR=168>\ \

<【/SCOLOR=253><追求极品神器的快感,我需要进行血祭/@我需要进行菩提><】/SCOLOR=253> <【/SCOLOR=168><我不是很懂得,想详细了解什么是血祭/@了解什么是菩提><】/SCOLOR=168>\ \


[@存放]
#IF
checkitem 血祭之灵 1
#ACT
take 血祭之灵 1
GAMEDIAMOND + 1
GuildNoticeMsg 251 139 ﹝<$USERNAME>﹞:爷倾家荡产总算搞到了一个[血祭之灵]!这玩意儿贵重!!得赶紧存起来!!!
goto @main
BREAK
#ELSEACT
MESSAGEBOX 【存放条件】:背包里必须至少有一个血祭之灵!点击一下存放一个!


[@取出]
#IF
CHECKGAMEDIAMOND > 0
#ACT
give 血祭之灵 1
GAMEDIAMOND - 1
GuildNoticeMsg 251 139 ﹝<$USERNAME>﹞:爷倾家荡产总算搞到了一个[血祭之灵]!这玩意儿稀有!!得赶紧用掉!!!
goto @main
BREAK
#ELSEACT
MESSAGEBOX 【取出条件】:银行里必须至少有一个血祭之灵!点击一下取出一个!







[@我需要进行菩提]
#IF
CHECKUSEITEM 1
#ACT
GOTO @开始菩提武器检测
BREAK
#ELSEACT
MESSAGEBOX [请注意]:你没有装备如何武器在手!
BREAK

[@开始菩提武器检测]
#IF
CHECKITEMADDVALUE 1 9 < 279
#ACT
MOV N88 0
GOTO @开始菩提武器
BREAK
#ELSEACT
MESSAGEBOX [请注意]:你的“<$WEAPON>”已经完成终极血祭,换一把再来吧!
BREAK

[@开始菩提武器]

#IF
Checkitem 血祭之灵 1
#ACT
CLOSEBigDialogBox
GOTO @菩提武器最终
BREAK
#ELSEACT
MESSAGEBOX [请注意]:包裹里没有“血祭之灵”,血祭自动中断!
GOTO @特殊提示
BREAK

[@特殊提示]
#IF
LARGE N88 0
#ACT
MESSAGEBOX 【系统提示】:本次血祭完成,请继续加油!
sendmsg 0 [血剑祭坛]:﹝<$USERNAME>﹞的<$WEAPON>完成了[<$STR(N88)>]次血祭,利剑逐渐展露锋芒.
MOV N88 0
CLOSE
BREAK




[@菩提武器最终]
#IF
CHECKUSEITEM 1
CHECKITEMADDVALUE 1 9 = 254
Checkitem 血祭之灵 1
#ACT
CLOSEBigDialogBox
TAKE 血祭之灵 1
UPGRADEITEMEX 1 9 0 1 0
UPGRADEITEMEX 1 0 0 1 0
UPGRADEITEMEX 1 1 0 1 0
UPGRADEITEMEX 1 2 0 1 0
SetNewItemValue 1 0 = 0
SetNewItemValue 1 1 = 0
SetNewItemValue 1 2 = 0
SetNewItemValue 1 3 = 0
SetNewItemValue 1 4 = 0
SetNewItemValue 1 5 = 0
SetNewItemValue 1 6 = 0
SetNewItemValue 1 7 = 0
SetNewItemValue 1 0 = 28
SetNewItemValue 1 1 = 13
SetNewItemValue 1 2 = 13
SetNewItemValue 1 3 = 13
SetNewItemValue 1 4 = 13
SetNewItemValue 1 5 = 13
MESSAGEBOX 【系统提示】:你完成了武器的终极血祭,手里利器已成为绝世神器!
SendCenterMsg 250 4 [血剑祭坛]:﹝<$USERNAME>﹞的<$WEAPON>完成了终极血祭,[+255]霸气极品[+13%]伤害灵魂属性.. 1 15
SendCenterMsg 254 4 [血剑祭坛]:﹝<$USERNAME>﹞的<$WEAPON>完成了终极血祭,[+255]霸气极品[+13%]伤害灵魂属性.. 1 20
GuildNoticeMsg 250 4 [血剑祭坛]:﹝<$USERNAME>﹞的<$WEAPON>完成了终极血祭,[+255]霸气极品[+13%]伤害灵魂属性..
BREAK
CLOSE

#IF
CHECKUSEITEM 1
CHECKITEMADDVALUE 1 9 < 255
Checkitem 血祭之灵 1
#SAY
\ \
<╔═══════════════════════════╗/SCOLOR=21>\
<║ ║/SCOLOR=21>\
<║/SCOLOR=21> <┌--------------------------------------┐/SCOLOR=250> <║/SCOLOR=21>\
<║/SCOLOR=21> <│/SCOLOR=250><请注意:装备菩提中,请耐心等待完成提示/SCOLOR=150><│/SCOLOR=250> <║/SCOLOR=21>\
<║/SCOLOR=21> <└--------------------------------------┘/SCOLOR=250> <║/SCOLOR=21>\
<║ ║/SCOLOR=21>\
<╚═══════════════════════════╝/SCOLOR=21>\
#ACT
CLOSEBigDialogBox
TAKE 血祭之灵 1
UPGRADEITEMEX 1 9 0 1 0
UPGRADEITEMEX 1 0 0 1 0
UPGRADEITEMEX 1 1 0 1 0
UPGRADEITEMEX 1 2 0 1 0
INC N88 1
DelayCall 100 @开始菩提武器
BREAK



[@了解什么是菩提]
#ACT
MESSAGEBOX 举个例子:\比如你现在手里拿着木剑,血祭一次增加1点攻魔道\一共可以血祭255次\那么最后一次血祭武器将增加13%的伤害元素属性
栏目列表